## vim:ft=zsh
## cvs support by: Frank Terbeck <ft@bewatermyfriend.org>
## Distributed under the same BSD-ish license as zsh itself.

setopt localoptions NO_shwordsplit
local cvsbranch cvsbase

# Look for the most distant parent that still has a CVS subdirectory.
# VCS_INFO_detect_cvs ensured that ./CVS/Repository exists.
cvsbase="."
cvsbase=${cvsbase:P}
while [[ -d "${cvsbase:h}/CVS" ]]; do
    cvsbase="${cvsbase:h}"
    if [[ $cvsbase == '/' ]]; then
        break
    fi
done

cvsbranch=$(< ./CVS/Repository)
rrn=${cvsbase:t}
cvsbranch=${cvsbranch##${rrn}/}
[[ -z ${cvsbranch} ]] && cvsbranch=${rrn}
VCS_INFO_formats '' "${cvsbranch}" "${cvsbase}" '' '' '' ''
return 0
