*syntax.txt*    For Vim version 5.0j.  Last modification: 1997 May 29


		  VIM REFERENCE MANUAL    by Bram Moolenaar


Syntax highlighting						*syntax*

Syntax highlighting enables the possibility to show parts of the text in
another font or color.  Those parts can be specific keywords or text
matching a pattern.  Vim doesn't parse the whole file (to keep it fast), so
the highlighting has its limitations.  Lexical highlighting might be a
better name, but everybody calls it syntax highlighting, so we'll stick with
that.

Vim supports syntax highlighting on all terminals.  But since most ordinary
terminals have very limited highlighting possibilities, it works best in the
GUI version, gvim.

1. Quick start		|syn-qstart|
2. Syntax files		|syn-files|
3. Syntax file remarks	|syn-file-remarks|
4. Defining a syntax	|syn-define|
5. :syntax arguments	|syn-arguments|
6. Synchronizing	|:syn-sync|
7. Listing syntax items	|:syntax|
8. Highlight command	|:highlight|
9. Linking groups	|:highlight-link|
10. Cleaning up		|:syn-clear|
11. Highlighting tags	|tag-highlight|
12. Color xterms	|xterm-color|

==============================================================================
1. Quick start						*syn-qstart*

For a few common languages syntax files have been included.  To make them work
include this line in your .vimrc or .gvimrc:

    source $VIM/syntax/syntax.vim

This will automatically enable syntax highlighting, depending on the file name
extension.  If the VIM environment variable is not set, Vim will try to find
the path in another way (see |$VIM|).  Normally this will work just fine.  If
it doesn't, try setting the VIM environment variable to the directory where
the Vim stuff is located.  For example, if your syntax files are in the
"/usr/vim/5.0/syntax" directory, set $VIM to "/usr/vim/5.0".

							*syn-default-override*
You can override the default highlight settings, by issuing ":highlight"
commands after sourcing "syntax.vim".  For example:

	source $VIM/syntax/syntax.vim
	highlight Constant guifg=NONE

This will remove the GUI foreground highlighting for the "Constant" group.
See ":highlight" about how to specify highlighting attributes.

==============================================================================
2. Syntax files						*syn-files*

The syntax and highlighting commands for one language are normally stored in
a syntax file.  The name convention is: "{name}.vim".  Where {name} is the
name of the language, or an abbreviation (to fit the name in 8.3 characters,
which is always done, in case the file will be used on a DOS filesystem).
Examples:
	c.vim		perl.vim	java.vim	html.vim
	cpp.vim		sh.vim		csh.vim

The syntax file can contain any Ex commands, just like a vimrc file.  But
the idea is that only commands for a specific language are included.  When a
language is a superset of another language, it may include the other one,
for example, the cpp.vim file could include the c.vim file:

	:so $VIM/syntax/c.vim

The .vim files are normally loaded with an autocommand.  For example:

	:au BufNewFile,BufReadPost *.c,*.h source $VIM/syntax/c.vim
	:au BufNewFile,BufReadPost *.cpp source $VIM/syntax/cpp.vim


NAMING CONVENTIONS

							*group-name*
To be able to allow each user to pick his favorite set of colors, there need
to be preferred names for highlight groups that are common for many languages.
These are the ones that are suggested to be used:

	*Comment	any comment

	*Constant	any constant
	 String		a string constant: "this is a string"
	 Character	a character constant: 'c', '\n'
	 Number		a number constant: 234, 0xff
	 Boolean	a boolean constant: TRUE, false
	 Float		a floating point constant: 2.3e10

	*Identifier	any variable name
	 Function	function name (also: methods for classes)

	*Statement	any statement
	 Conditional	if, then, else, endif, switch, etc.
	 Repeat		for, do, while, etc.
	 Label		case, default, etc.
	 Operator	"sizeof", "+", "*", etc.
	 Keyword	any other keyword

	*PreProc	generic Preprocessor
	 Include	preprocessor #include
	 Define		preprocessor #define
	 Macro		same as Define
	 PreCondit	preprocessor #if, #else, #endif, etc.

	*Type		int, long, char, etc.
	 StorageClass	static, register, volatile, etc.
	 Structure	struct, union, enum, etc.
	 Typedef	A typedef
	
	*Special	any special symbol

	*Error		any erroneous construct

	*Todo		anything that needs extra attention

The ones marked with * are the preferred groups, the other are minor groups.
For the preferred groups, the "syntax.vim" file contains default highlighting.
The minor groups are linked to the preferred groups, so they get the same
highlighting.  You can override these defaults by giving ":highlight" commands
after sourcing the "syntax.vim" file.

Note that highlight group names are not case sensitive.  "String" and "string"
can be used for the same group.

The following names are reserved and cannot be used as a group name:
	NONE   ALL   ALLBUT   contains   contained

==============================================================================
3. Syntax file remarks					*syn-file-remarks*

sh.vim

This covers the "normal" Unix sh, bash and the korn shell.  If you're working
on a system where bash is called sh, you will benefit to define the vim
variable 'bash_is_sh' in your '.vimrc' file:
	let bash_is_sh = 1

To choose between the two ways to treat single-quotes inside a pair of
double-quotes, I have introduced a Vim variable "highlight_balanced_quotes".
By default (ie by not declaring this variable) single quotes can be used
inside double quotes, and are not highlighted.  If you prefer balanced single
quotes as I do you just make the statement in your .vimrc file:
        let highlight_balanced_quotes = 1

Similar I have introduced another vim variable "highlight_function_name" to be
used to enable/disable highlighting of the function-name in function
declaration.  Default is not to highlight the function name.  If you want to
highlight functions names, include this in your .vimrc file:
        let highlight_function_name = 1

==============================================================================
4. Defining a syntax					*syn-define*

Vim understands three types of syntax items:
1. A keyword.  It can only contain keyword characters, according to the
   'iskeyword' option.  It cannot contain other syntax items.  It will only
   be recognized when it is a complete match (there are no keyword
   characters before or after the match).  "if" would match in "if(a=b)",
   but not in "ifdef x".
2. A match.  This is a match with a single regexp pattern.  It must be within
   one line.
3. A region.  This starts at a match of the start regexp pattern and
   ends with a match with the end regexp pattern.  A skip regexp pattern can
   be used to avoid matching the end pattern.

Several syntax ITEMs can be put into one syntax GROUP.  For a syntax group
you can give highlighting attributes.  For example, you could have an item
to define a /* .. */ comment and another one that defines a // comment, and
put them both in the "Comment" group.  You can then specify that a "Comment"
will be in bold font and have a blue color.  You are free to make one
highlight group for one syntax item, or put all items into one group.  This
depends on how you want to specify your highlighting attributes.  Putting
each item in its own group results in having to specify the highlighting
for a lot of groups.

Note that a syntax group and a highlight group are similar.  For a highlight
group you will have given highlight attributes.  These attributes will be used
for the syntax group with the same name.

In case more than one items match at the same position, the one that was
defined first wins.  But a keyword always goes before a match or region.  And
a keyword with matching case always goes before a keyword with ignoring case.


DEFINING CASE						*:syn-case*

:syntax case [match|ignore]
	This defines if the following ":syntax" commands will work with
	matching case, when using "match", or with ignoring case, when using
	"ignore".  Note that any items before this are not affected, and all
	items until the next ":syntax case" command are affected.


DEFINING KEYWORDS					*:syn-keyword*

:syntax keyword {group-name} {options} {keyword} ..

	This defines a number of keywords.

	{group-name}	Is a syntax group name such as "Comment".
	{options}	See |syn-arguments| below.
	{keyword} ..	Is a list of keywords which are part of this group.

	Example:

    :syntax keyword   Type   int long char

	A keyword always has higher priority than a match or region, if more
	than one item matches.  Keywords do not nest and a keyword can't
	contain anything else.

	Note that when you have a keyword that is the same as an option (even
	one that isn't allowed here), you can not use it as the first item in
	the list of keywords.  Put another keyword before it.  Example:

    :syntax keyword   vimSpecial  dummy grouphere

    	The maximum length of a keyword is 80 characters.


DEFINING MATCHES					*:syn-match*

:syntax match {group-name} {options} {pattern} [contains {group-name} ..]

	This defines one match.

	{group-name}	A syntax group name such as "Comment".
	{options}	See |syn-arguments| below.
	{pattern}	The search pattern that defines the match.  See
			|syn-pattern| below.
	[contains ..]	The syntax groups that the match may contain.  See
			|:syn-contains| below.

	Example (match a character constant):

    :syntax match Character /'.'/s+1e-1


DEFINING REGIONS	*:syn-region* *:syn-start* *:syn-skip* *:syn-end*

:syntax region {group-name} {options}
		start={start_pattern} ..
		[skip={skip_pattern}]
		end={end_pattern} ..
		[contains {group-name} ..]

	This defines one region.  It may span several lines.

	{group-name}		A syntax group name such as "Comment".
	{options}		See |syn-arguments| below.
	start={start_pattern}	The search pattern that defines the start of
				the region.  See |syn-pattern| below.
	skip={skip_pattern}	The search pattern that defines text inside
				the region where not to look for the end
				pattern.  See |syn-pattern| below.
	end={end_pattern}	The search pattern that defines the end of
				the region.  See |syn-pattern| below.
	[contains {group-name} ..]
				The syntax groups that the match may contain.
				See |:syn-contains| below.

	Example:

    :syntax region String   start=+"+  skip=+\\"+  end=+"+

	The start/skip/end patterns can be given in any order.  There can be
	zero or one skip pattern.  There must be one or more start and end
	patterns.  This means that you can omit the skip pattern, but you
	must give at least one start and end pattern.  It is allowed to have
	white space before and after the equal sign (although it mostly looks
	better without white space).

	When more than one start pattern is given, a match with one of these
	is sufficient.  This means there is an OR relation between the start
	patterns.  The same is true for the end patterns.

==============================================================================
5. :syntax arguments					*syn-arguments*

The :syntax commands that define syntax items take a number of arguments.
The common ones are explained here.

Not all commands accept all arguments.  This table shows which arguments
can be used for each command:

			contained    transparent    contains	oneline
:syntax keyword		   yes		  -		-	   -
:syntax match		   yes		 yes	       yes	   -
:syntax region		   yes		 yes	       yes	  yes

							*:syn-contained*
When the "contained" argument is given, this item will not be recognized at
the top level, but only when it is mentioned in the "contains" field of
another match.  Example:

    :syntax keyword Todo    contained  TODO
    :syntax match   Comment            "//.*"   contains Todo

							*:syn-transparent*
If the "transparent" argument is given, this item will not be highlighted
itself, but will take the highlighting of the item it is contained in.  This
is useful for syntax items that don't need any highlighting but are used
only to skip over a part of the text.  The same groups as the item it is
contained in are used, unless a "contains" argument is given too.

							*:syn-contains*
The "contains" argument is followed by a list of syntax group names.  These
groups will be accepted inside the item.  This allows for recursive nesting
of matches and regions.  If there is no "contains" argument, no groups will
be contained in this item.  The group names do not need to be defined before
they can be used here.

contains ALL
		If the only item in the contains list is "ALL", then all
		groups will be accepted inside the item.

contains ALLBUT {group-name} ..
		If the first item in the contains list is "ALLBUT", then all
		groups will be accepted inside the item, except the ones that
		are listed, and the "contained" items.  Example:

    :syntax region Block start="{" end="}" ... contains ALLBUT Function

The {group-name} in the "contains" list can be a pattern.  All group names
that match the pattern will be included (or excluded, if "ALLBUT" is used).
The pattern cannot contain white space.  Example:

    ... contains Comment.* Keyw[0-3]

							*:syn-oneline*
The "oneline" argument indicates that the region does not cross a line
boundary (except when a contained item does).

							*syn-pattern*
In the commands above, a pattern must be surrounded by two identical
characters.  This is like it works for the ":s" command.  The most common to
use is the double quote.  But if the pattern contains a double quote, you can
use another character that is not used in the pattern.  Examples:

    :syntax region Comment  start="/\*"  end="\*/"
    :syntax region String   start=+"+    end=+"+   skip=+\\"+

See |pattern| for the explanation of what a pattern is.  Syntax patterns are
always interpreted like the 'magic' options is set, no matter what the actual
value of 'magic' is.  This was done to make syntax files portable.

Try to avoid patterns that can match an empty string, such as "[a-z]*".
This slows down the highlighting a lot, because it matches everywhere.

The pattern can be followed by a character offset.  This can be used to
change the highlighted part, and to change the text area included in the
match or region (which only matters when trying to match other items).  Both
are relative to the matched pattern.  The character offset for a skip
pattern can be used to tell where to continue looking for an end pattern.

offset	meaning for match/region-start/region-end/skip

S+{N}	matched text starts/starts/ends/ends N characters to the right of
	the START of the matched pattern.
S-{N}	matched text starts/starts/ends/ends N characters to the left of
	the START of the matched pattern.
E+{N}	matched text   ends/starts/ends/ends N characters to the right of
	the END   of the matched pattern.
E-{N}	matched text   ends/starts/ends/ends N characters to the left of
	the END   of the matched pattern.
s+{N}	highlighting starts/starts/ends/@    N characters to the right of
	the START of the matched pattern
s-{N}	highlighting      */starts/ends/@    N characters to the left of
	the START of the matched pattern.
e+{N}	highlighting      */starts/ends/@    N characters to the right of
	the END   of the matched pattern.
e-{N}	highlighting   ends/starts/ends/@    N characters to the left of
	the END   of the matched pattern

*  means that it's not possible for a match, because it would mean that the
   highlighted area would go outside of the matched text.
@  means that it's not used for a skip pattern, because only the matched
   text matters.

Notes:
- Several offsets may be concatenated.
- There must be no white space between the pattern and the character
  offset(s).
- The highlighted area will never be outside of the matched text.
- There is a difference between the use of an offset for a match and for a
  region, because a match has only one pattern and a region has two patterns.
  Consequently, for a match you can only define the start of the matching text
  or highlighting relative to the start of the matched pattern, while for a
  region you can also give the start of the matching text or highlighting
  relative to the end of the matched pattern.  Example:
	    syntax match Foo "pattern"s+1e-1
	highlights the matched pattern, excluding the first and last
	characters.
	    syntax region Bar start="spat"e-1 end="epat"s+1
	highlights from the matched start pattern, last but one character,
	until the matched end pattern, second character.

Example (match a character constant but don't highlight the quotes):

    :syntax match Character /'.'/s+1e-1

Example (match a comment but don't highlight the /* and */):

    :syntax region Comment start="/\*"e+1 end="\*/"s-1

==============================================================================
6. Synchronizing					*:syn-sync*

Vim wants to be able to start redrawing in any position in the document.  To
make this possible it needs to know the syntax item at the position where
redrawing starts.

:syntax sync [ccomment [group-name] | minlines={N} | ...]

There are three ways to synchronize:
1. Based on C-style comments.  Vim understands how C-comments work and can
   figure out if the current line starts inside or outside a comment.
2. Jumping back a certain number of lines and start parsing there.
3. Searching backwards in the text for a pattern to sync on.

For all three methods, the line range where the parsing can start is limited
by "minlines" and "maxlines".

If the "minlines={N}" argument is given, the parsing always starts at least
that many lines backwards.  This can be used if the parsing may take a few
lines before it's correct, or when it's not possible to use syncing.

If the "maxlines={N}" argument is given, the number of lines that are searched
for a comment or syncing pattern is restricted to N lines backwards (after
adding "minlines".  This is useful if you have few things to sync on and a
slow machine.  Example:

    :syntax sync ccomment maxlines=500


First syncing method:

For the first method, only the "ccomment" argument needs to be given.
Example:

    :syntax sync ccomment

When Vim finds that the line where displaying starts is inside a C-style
comment, the first region syntax item with the group-name "Comment" will be
used.  This requires that there is a region with the group-name "Comment"!
An alternate group name can be specified, for example:

    :syntax sync ccomment javaComment

The "maxlines" argument can be used to restrict the search to a number of
lines.  The "minlines" argument can be used to at least start a number of
lines back (e.g., for when there is some construct that only takes a few
lines, but it hard to sync on).

Note: Syncing on a C comment doesn't work properly when strings are used
that cross al line and contain a "*/".  Since letting strings cross a line
is a bad programming habit (many compilers give a warning message), and the
chance of a "*/" appearing inside a comment is very small, this restriction
is hardly ever noticed.


Second syncing method:

For the second method, only the "lines={N}" argument needs to be given.  Vim
will subtract {N} from the line number and start parsing there.  This means
{N} extra lines need to be parsed, which makes this method a bit slower.
Example:

    :syntax sync lines=50

"lines" and "minlines" are equivalent.


Third syncing method:

The idea is to synchronize on the end of a few specific regions, called a
sync pattern.  Only regions can cross lines, so when we find the end of some
region, we might be able to know in which syntax item we are.  The search
starts in the line just above the one where redrawing starts.  From there
the search continues backwards in the file.

A line continuation pattern can be given here.  It is used to decide which
group of lines need to be searched like they were one line.  This means that
the search for a match with the specified items starts in the first of the
consecutive that contain the continuation pattern.

When a match with a sync pattern is found, the rest of the line (or group of
continuated lines) is searched for another match.  The last match is used.
This is used when a line can contain both the start end the end of a region
(e.g., in a C-comment like /* this */, the last "*/" is used).

There are two ways how a match with a sync pattern can be used:
1. Parsing for highlighting starts where redrawing starts (and where the
   search for the sync pattern started).  The syntax group that is expected
   to be valid there must be specified.  This works well when the regions
   that cross lines cannot contain other regions.
2. Parsing for highlighting continues just after the match.  The syntax group
   that is expected to be present just after the match must be specified.
   This can be used when the previous method doesn't work well.  It's much
   slower, because more text needs to be parsed.
Both types of sync patterns can be used at the same time.

Besides the sync patterns, other matches and regions can be specified, to
avoid finding unwanted matches.

[The reason that the sync patterns are given separately, is that mostly the
search for the sync point can be much simpler than figuring out the
highlighting.  The reduced number of patterns means it will go (much)
faster.]

    :syntax sync match {group-name} grouphere {sync-group-name} ..

	Define a match that is used for syncing.  {sync-group-name} is the
	name of a syntax group that follows just after the match.  Parsing
	of the text for highlighting starts just after the match.  A region
	must exist for this sync-group-name.  The first one defined will be
	used.  "NONE" can be used for when there is no syntax group after the
	match.

    :syntax sync match {group-name} groupthere {sync-group-name} ..

	Like "grouphere", but {sync-group-name} is the name of a syntax
	group that is to be used at the start of the line where searching
	for the sync point started.  The text between the match and the
	start of the sync pattern searching is assumed not to change the
	syntax highlighting.

    :syntax sync match ..
    :syntax sync region ..

	Define a region or match that is skipped while searching for a sync
	point.

    :syntax sync linecont {pattern}

        When {pattern} matches in a line, it is considered to continue in
	the next line.  This means that the search for a sync point will
	consider the lines to be concatenated.

If the "maxlines={N}" argument is given too, the number of lines that are
searched for a match is restricted to N.  This is useful if you have very
few things to sync on and a slow machine.  Example:

    :syntax sync maxlines=100

You can clear sync patterns with:

    :syntax sync clear {group-name} ..

==============================================================================
7. Listing syntax items					*:syntax*

This commands lists all the syntax items:

:syntax [list]

To show the syntax items for one syntax group:

:syntax list {group-name}

See above for other arguments for the ":syntax" command.

==============================================================================
8. Highlight command					*:highlight*

There are two types of highlight groups:
- The ones used for specific languages.  For these the name starts with the
  name of the language.  Many of these don't have any attributes, but are
  linked to a group of the second type.
- The ones used for all languages.  These are also used for the 'highlight'
  option.

:highlight		List all the current highlight groups that have
			attributes set.

:highlight {group-name}
			List one highlight group.

:highlight {group-name} NONE
			Disable the highlighting for one highlight group.

:highlight {group-name} {key}={arg} ..
			Add a highlight group, or change the highlighting for
			an existing group.  See below for the arguments
			|highlight-args|.

Normally a highlight group is added once, in the *.vim file.  This sets
the default values for the highlighting.  After that, you can use additional
highlight commands to change the arguments that you want to set to
non-default values.  The value "NONE" can be used to switch the value off or
go back to the default value.

						*highlight-args*
There are three types of terminals for highlighting:
- a normal terminal (vt100, xterm)
- a color terminal (MS-DOS console, color-xterm, these have the "Co" termcap
  entry)
- the GUI

For each type the highlighting can be given.  This makes it possible to use
the same syntax file on all terminals, and use the optimal highlighting.

1. highlight arguments for normal terminals

term={attr-list}				*attr-list*
	attr-list is a comma separated list (without spaces) of the
	following items (in any order):
		bold
		underline
		reverse
		inverse		same as reverse
		italic
		standout
		NONE		no attributes used (used to reset it)

	Note that "bold" can be used here and by using a bold font.  They
	have the same effect.

start={term-list}
stop={term-list}				*term-list*
	These lists of terminal codes can be used to get
	non-standard attributes on a terminal.

	The escape sequence specified with the "start" argument
	is written before the characters in the highlighted
	area.  It can be anything that you want to send to the
	terminal to highlight this area.  The escape sequence
	specified with the "stop" argument is written after the
	highlighted area.  This should undo the "start" argument.
	Otherwise the screen will look messed up.

	The {term-list} can have two forms:

	1. A string with escape sequences.
	   This is any string of characters, except that it can't start with
	   "t_" and blanks are not allowed.  The <> notation is recognized
	   here, so you can use things like "<Esc>" and "<Space>".  Example:
		start=<Esc>[27h;<Esc>[<Space>r;

	2. A list of terminal codes.
	   Each terminal code has the form "t_xx", where "xx" is the name of
	   the termcap entry.  The codes have to be separated with commas.
	   White space is not allowed.  Example:
		start=t_C1,t_BL
	   The terminal codes must exist for this to work.


2. highlight arguments for color terminals

cterm={attr-list}
	See above for the description of {attr-list} |attr-list|.
	The "cterm" argument is likely to be different from "term", when
	colors are used.  For example, in a normal terminal comments could
	be underlined, in a color terminal they can be made Blue.

ctermfg={color-nr}
ctermbg={color-nr}
	The {color-nr} argument is a color number.  Its range is zero to
	(not including) the number given by the termcap entry "Co".
	The actual color with this number depends on the type of terminal
	and its settings.
	
	For an xterm this depends on your resources, and is a bit
	unpredictable.  See your xterm documentation for the defaults.  The
	colors for a color-xterm can be changed from the .Xdefaults file.
	Unfortunately this means that it's not possible to get the same colors
	for each user.  See |xterm-color| for info about color xterms.
	
	The MSDOS standard colors are fixed (in a console window), so these
	have been used for the names.  But the meaning of color names in X11
	are fixed, so these color settings have been used, to make the
	highlighting settings portable (complicated, isn't it?).  The
	following names are recognized, with the color number used:

		NR	COLOR NAME

		0	Black
		1	DarkBlue
		2       DarkGreen
		3       DarkCyan
		4       DarkRed
		5       DarkMagenta
		6       Brown
		7       LightGray, LightGrey, Gray, Grey
		8	DarkGray, DarkGrey
		9	Blue, LightBlue
		10	Green, LightGreen
		11	Cyan, LighCyan
		12	Red, LightRed
		13	Magenta, LightMagenta
		14	Yellow
		15	White

	The case of the color names is ignored.
	
	Note that for some color terminals these names may result in the wrong
	colors!

3. highlight arguments for GUI

gui={attr-list}
	These give the attributes to use in the GUI mode.
	See |attr-list| for a description.
	Note that "bold" can be used here and by using a bold font.  They
	have the same effect.

font={font-name}
	font-name is the name of a font, as it is used on the system Vim
	runs on.  For X11 this is a complicated name, for example:

	    font=-misc-fixed-bold-r-normal--14-130-75-75-c-70-iso8859-1

	The font-name "NONE" can be used to revert to the default font.
	All fonts used should be of the same character size as the default
	font!

guifg={color-name}
guibg={color-name}
	These give the foreground (guifg) and background (guibg) color to
	use in the GUI.  There are a few special names:
		NONE		no color (transparant)
		bg		use normal background color
		background	use normal background color
		fg		use normal foreground color
		foreground	use normal foreground color

	Suggested color names (these are available on most systems) TODO:
	    Blue	LightBlue	DarkBlue
	    Red		BrightRed	LightRed	DarkRed
	    Green	LightGreen	DarkGreen
	    Cyan	BrightCyan
	    Magenta
	    Yellow
	    Gray	LightGray	DarkGray
	    Black
	    White

	You can also specify a color by it's Red, Green and Blue values.
	The format is "#rrggbb", where
		"rr"	is the Red value
		"bb"	is the Blue value
		"gg"	is the Green value
	All values are hexadecimal, range from "00" to "ff".  Examples:

    :highlight Comment guifg=#11f0c3 guibg=#ff00ff

							*highlight-default*
These are the default highlighting groups.  These groups are used by the
'highlight' option default:
    SpecialKey  term=bold ctermfg=Blue guifg=Blue
    WinEnd	term=bold ctermbg=LightGrey guibg=LightGrey
    Directory   term=bold ctermfg=Blue guifg=Blue
    ErrorMsg    term=standout ctermbg=LightRed guibg=Orange
    Search	term=reverse ctermbg=Yellow guibg=Yellow
    MoreMsg	term=bold cterm=bold ctermfg=Green gui=bold guifg=Green
    ModeMsg	term=bold cterm=bold gui=bold
    LineNr	term=underline ctermfg=Brown guifg=Brown
    Question    term=standout cterm=bold ctermfg=Green gui=bold guifg=Green
    StatusLine  term=reverse cterm=reverse gui=reverse
    Title	term=bold cterm=bold ctermfg=Blue gui=bold guifg=Blue
    Visual	term=reverse cterm=reverse gui=reverse
    WarningMsg  term=standout ctermfg=Red guifg=Red
    Cursor	guibg=Green

==============================================================================
9. Linking groups					*:highlight-link*

When you want to use the same highlighting for several syntax groups, you
can do this more easily by linking the groups into one common highlight
group, and give the color attributes only for that group.

    :highlight[!] link {from-group} {to-group}

Notes:
- If the {from-group} and/or {to-group} doesn't exist, it is created.  You
  don't get an error message for a non-existing group.
- If the {to-group} is "NONE", the link is removed from the {from-group}.
- As soon as you use a ":highlight" command for a linked group, the link is
  removed.
- If there are already highlight settings for the {from-group}, the link is
  not made, unless the '!' is given.  For a ":highlight link" command in a
  sourced file, you don't get an error message.  This can be used to skip
  links for groups that already have settings.

==============================================================================
10. Cleaning up						*:syn-clear*

If you want to clear the syntax stuff for the current buffer, you can use this
command:

    :syntax clear

This command should be used when you want to switch off syntax highlighting,
or when you want to switch to using another syntax.  It's a good idea to
include this command at the beginning of a syntax file.


To clean up specific syntax groups for the current buffer:

    :syntax clear {group-name} ..

This removes all patterns and keywords for {group-name}.

==============================================================================
11. Highlighting tags					*tag-highlight*

If you want to highlight all the tags in your file, you can use the following
mappings.

	<F11>	-- Generate tags.vim file, and highlight tags.
	<F12>	-- Just highlight tags based on existing tags.vim file.

map <F11>  :sp tags<CR>:%s/^\([^ 	:]*:\)\=\([^ 	]*\).*/syntax keyword Tag \2/<CR>:wq! tags.vim<CR><F12>
map <F12>  :so tags.vim<CR>

WARNING: The longer the tags file, the slower this will be, and the more
memory Vim will consume.

==============================================================================
12. Color xterms					*xterm-color*

Most color xterms have only eight colors.  They should work with these
settings:
	:set t_Co=8
	:set t_Sf=<Esc>[3%dm
	:set t_Sb=<Esc>[4%dm
	[<Esc> is a real escape, type CTRL-V <Esc>]

To get 16 colors, get the newest xterm version (which should be included with
Xfree86 3.3).  You can also find the latest version at:
	http://www.clark.net/pub/dickey/xterm
This one should work with these settings:
	:set t_Co=16
	:set t_AB=^[[%?%p1%{8}%<%t%p1%{40}%+%e%p1%{92}%+%;%dm
	:set t_AF=^[[%?%p1%{8}%<%t%p1%{30}%+%e%p1%{82}%+%;%dm

You might want to use the X resouces (put them in your .Xdefaults file):
        XTerm*color0:                   #000000
        XTerm*color1:                   #c00000
        XTerm*color2:                   #00c000
        XTerm*color3:                   #c0c000
        XTerm*color4:                   #0000c0
        XTerm*color5:                   #c000c0
        XTerm*color6:                   #00c0c0
        XTerm*color7:                   #c0c0c0
        XTerm*color8:                   #808080
        XTerm*color9:                   #ff0000
        XTerm*color10:                  #00ff00
        XTerm*color11:                  #ffff00
        XTerm*color12:                  #0000ff
        XTerm*color13:                  #ff00ff
        XTerm*color14:                  #00ffff
        XTerm*color15:                  #ffffff

To get these right away, reload the .Xdefaults file to the X Option database
Manager (you only need to do this when you just changed the .Xdefaults file):
        xrdb -merge ~/.Xdefaults

 vim:tw=78:ts=8:sw=4
