@echo off
REM hfont.cmd -- written by koaunghi.un@zdv.uni-tuebingen.de
REM read pk-files in %dir%\pixel.%mode%\@Rrdpi
REM write fli file in %dir%

REM Please edit these lines.
REM "mode" is for printer, which you have. See \emtex\mfjob\modes.mfj
REM "res" is the resolution of above printer. See also modes.mfj
REM "hangul" and "hextra" are for hangul fonts, which you intend to use.
REM	If you omit some fonts for hangul, edit the line "fonts=" in
REM	\emtex\mfjob\hangul.mfj and/or \emtex\mfjob\hextra.mfj.
REM "hanja" is for hanja fonts.
REM "dir" is normally c:\texfonts, where the pk and fli files go.
REM set "del_pk" to "no", if you want to keep pk files alive. Once you have
REM	fli files, you don't need them anymore.
REM "mf_opt" is the option for running mfjob.

set mode=lj
set res=300
set hangul=mj gt
set hextra=gr gs yt mg ol
set hanja=mj gt
set symbol=mj
set dir=c:\texfonts
set del_pk=yes
set mfj_opt=/3

REM No need to change lines below.

:hangul
if %hangul%/ == / goto hextra
mfjob %mfj_opt% hangul.mfj
for %%I in (%hangul%) do call hfontfli /v %mode% %res% %dir% hangul %%I
call hfontfli /v %mode% %res% %dir% hsymbol mj
if %del_pk%/ == no/ goto hextra
emdelete -s -y -f %dir%\pixel.%mode%\ws*.pk
emdelete -s -y -f %dir%\pixel.%mode%\hsmj*.pk

:hextra
if %hextra%/ == / goto hanja
mfjob %mfj_opt% hextra.mfj
for %%I in (%hextra%) do call hfontfli /v %mode% %res% %dir% hangul %%I
if %del_pk%/ == no/ goto hanja
emdelete -s -y -f %dir%\pixel.%mode%\ws*.pk

:hanja
if %hanja%/ == / goto end
mfjob %mfj_opt% hanja.mfj
for %%J in (%hanja%) do call hfontfli /v %mode% %res% %dir% hanja %%J
if %del_pk%/ == no/ goto end
emdelete -s -y -f %dir%\pixel.%mode%\hh*.pk

:end

set mode=
set res=
set hangul=
set hextra=
set hanja=
set symbol=
set dir=
set del_pk=
set mfj_opt=