
The following simple example is for both polarizations of
one sub band, LI or UO, of one band, E090, of the EMIR receiver, 
see the EMIR user's guide for more information. 

\begin{itemize}

\item {Prepare a source catalog file, e.g., my.sou, with one line for each source that looks like:}

\small
\begin{verbatim}
W3OH EQ 2000 02:27:03.8812 +61:52:24.572 LSR -45.000    
\end{verbatim}
\normalsize

\item {Prepare a line catalog file, e.g., my.lin, with one text line for each line frequency like:}

\small
\begin{verbatim}
CS(2-1)         97.980968       LI
12CO(1-0)       115.271204      UO
\end{verbatim}
\normalsize

\command{LI} and \command{LO} refer to sub bands of the EMIR E090 band. 
See the EMIR user's guide for details.

\item {Start up \pako\ (see local information how to do this).}

\item {Enter some general options and information.}

\small
\begin{verbatim}
SIC PRIORITY 1 PAKO                 ! PAKO commands get precedence
SET LEVEL   0   0                   ! to get verbose chatter from pako
SET Project 111-22                  ! project ID (project number)
SET PI       "Dr. Lilo D. Doe"      ! principal investigator
SET Observer "John Doe"             ! 
SET Operator  Pako                  ! 
SET Topology  low                   ! topology for azimuth
SET doSubmit  YES                   ! allow submission to Queue
SHOW                                ! show parameters set with set
\end{verbatim}
\normalsize

\item {Specify the line catalog and the receiver setup.}

\small
\begin{verbatim}
CATALOG  line my.lin                ! specify (your) line catalog
RECEIVER /CLEAR                     ! clear any previous RX setup
RECEIVER E090 12CO(1-0) /Horizontal /Vertical
\end{verbatim}
\normalsize

The options \option{/Horizontal /Vertical} mean 
that both polarizations will be used.

\item {Select your target source from your catalog; select a backend 
       and do a calibration without sky to send the receiver setup.}

\small
\begin{verbatim}
CATALOG SOURCE my.sou               !  select your source catalog
SOURCE  W3OH                        !  source W3OH from your catalog
BACKEND /CLEAR                      !  clear any previous Backend setup
BACKEND WILMA /default              !  simple spectrometer setup for EMIR
BACKEND 4MHz  /default              !  simple spectrometer setup for EMIR
CALIBRATE /SKY NO                   !  doesn't need to move to sky position
START                               !  start
\end{verbatim}
\normalsize

\item {Let the operator tune the reciver(s)}

\item {Do a full calibration on the source, with default parameters:}

\small
\begin{verbatim}
CALIBRATE  /DEFAULT                 !  default calibration
START                               !  start
\end{verbatim}
\normalsize

\item {Look at the results and check with the operator if the 
receiver noise temperature is OK.}


\item {Select a strong compact continuum source for pointing and focussing; 
if possible, choose a source that is smaller than your beam!}

\small
\begin{verbatim}
SOURCE  2251+158 /catalog iram-J2000.sou ! pointing source from catalog
SOURCE  Uranus                           ! OR: a ``small'' planet
\end{verbatim}
\normalsize

\item{Select the continuum backend for pointing and focus.}

\small
\begin{verbatim}
BACKEND  /CLEAR
BACKEND  BBC  /Default
\end{verbatim}
\normalsize

\command{BACKEND  BBC  /Default} connects one part of the continuuum
backend BBC to each polarization and sideband of each selected EMIR band.

\item {Select beam switching mode and do a pointing.}

\small
\begin{verbatim}
SWBEAM                              !  to select beam switching
POINTING /default                   !  pointing
START                               !  start
\end{verbatim}
\normalsize

\item {After a pointing the data processing software displays the results
and you can enter a correction for the observed pointing offsets 
with the command. Let's say, the results are $+3.4$ and $-1.2$ [arc sec]}

\small
\begin{verbatim}
SET POINTING 3.4 -1.2
\end{verbatim}
\normalsize

\item {Do a focus measurement.}

\small
\begin{verbatim}
FOCUS            2.0                !  length [mm]
START                               !  start
\end{verbatim}
\normalsize

\item {After a focus the data processing software displays the results
and you can enter a new focus correction, e.g., $-2.1$~mm,
with the command:}

\small
\begin{verbatim}
SET FOCUS -2.1
\end{verbatim}
\normalsize


\item {Select a pointing source that is near your target source and 
do another pointing measurement and enter the resulting correction.}


\item {Select the target source from your catalog; select a backend 
       and do a calibration.}

\small
\begin{verbatim}
SOURCE  W3OH                        !  source W3OH from your catalog
BACKEND /CLEAR                      !  clear any previous Backend setup
BACKEND WILMA /default              !  simple spectrometer setup for EMIR
BACKEND 4MHz  /default              !  simple spectrometer setup for EMIR
CALIBRATE     /DEFAULT              !  default calibration
START                               !  start
\end{verbatim}
\normalsize

\command{BACKEND  WILMA  /Default} connects one part of the WILMA
spectrometer to each EMIR sub band selected with \command{RECEIVER}.
\command{BACKEND  4MHz   /Default} connects one part of the WILMA
spectrometer to 2 EMIR sub bands selected with \command{RECEIVER}.
\footnote{
Other spectrometers, e.g., VESPA, offer much more flexibility,
but also need more parameters and more explicit \command{BACKEND} commands,
see the following sections.
}

\item {Select your switching and observing mode, e.g., 
wobbler switching  and on-off, and start observing.}

\small
\begin{verbatim}
SWWOBBLER -120.0 120.0 /TPHASE 2.0          !  wobbler -/+ 120 arc sec
                                            !  2 seconds per phase
ONOFF /NSUBSCANS 12 /SYMMETRIC /TSUBSCAN 30 !  12 subscans
                                            !  "symmetric" subscan sequence
                                            !  30 sec per subscans
START
\end{verbatim}
\normalsize

\item {Do a calibration at least every 15 minutes,
or when you change sources,
or when you change receiver and backend setups.}

\item {Do a pointing every 2 hours or when you change to a different region
of the sky.}

\item {Do a focus every 6 hours and after sunset and sunrise. 
      \newline (Before focus, do a pointing on the focus source!)}

\item {HAVE FUN!}

\notes. 

\pako\ has built-in help for all commands, e.~g., 

\small
\begin{verbatim}
HELP SWWOBBLER
HELP ONOFF /NSUBSCANS
\end{verbatim}
\normalsize

Most commands can be abbreviated substantially, e.~g., the following 2 are equivalent:

\small
\begin{verbatim}
ON /NS 16 /SYM /TS 22
ONOFF /NSUBSCANS 16 /SYMMETRIC /TSUBSCAN 22 
\end{verbatim}
\normalsize


If you find that you enter the same command(s) very often, it is not
necessary to type them every time!  They can be put into command ``scripts''
either by editing a file or with \pako's \command{SAVE} command, see 
section \ref{sec-perplexed}.

\end{itemize}



