################################################################
# Qwt Widget Library
# Copyright (C) 1997   Josef Wilgen
# Copyright (C) 2002   Uwe Rathmann
#
# This library is free software; you can redistribute it and/or
# modify it under the terms of the Qwt License, Version 1.0
################################################################

include ( ./qwtconfig.pri )
include ( ./qwtfunctions.pri )

contains(QWT_CONFIG, QwtDll) {

    DEFINES *= QWT_DLL
}

contains(QWT_CONFIG, QwtSvg) {

    QT      *= svg
}
else {

    DEFINES *= QWT_NO_SVG
}

contains(QWT_CONFIG, QwtFramework) {

    INCLUDEPATH *= $${QWT_INSTALL_LIBS}/qwt.framework/Headers
    LIBS        *= -F$${QWT_INSTALL_LIBS}
}
else {

    INCLUDEPATH *= $${QWT_INSTALL_HEADERS}
    LIBS        *= -L$${QWT_INSTALL_LIBS}
}   

qwtAddLibrary(qwt)

linux-g++ {

    # when using the gold linker ( Qt < 4.8 ) - might be 
    # necessary on non linux systems too
    QMAKE_LFLAGS += -lrt
}

