# -*- coding: utf-8; mode: tcl; tab-width: 4; indent-tabs-mode: nil; c-basic-offset: 4 -*- vim:fenc=utf-8:ft=tcl:et:sw=4:ts=4:sts=4

PortSystem          1.0
PortGroup           legacysupport 1.1
PortGroup           openssl 1.0

# dprintf
legacysupport.newest_darwin_requires_legacy 10

name                proftpd
version             1.3.9c
revision            0
checksums           rmd160  eec43e8d29f4ea3397cef88289068446b7d43a4d \
                    sha256  724a6aead2f4a284c1df0c96ad778da2a45d38474bb46db8db0921d2b222f300 \
                    size    19860657

categories          net
license             GPL-2+
maintainers         {@BjarneDMat mathiesen.info:macintosh} openmaintainer

description         Highly configurable ftp-server.
long_description    ProFTPD is a highly configurable ftp daemon for unix \
                    and unix-like operating systems. ProFTPD is designed \
                    to be somewhat of a "drop-in" replacement for wu-ftpd \
                    with a configuration format like Apache.
homepage            http://www.proftpd.org
platforms           darwin freebsd
master_sites        ftp://ftp.proftpd.org/distrib/source/ \
                    ftp://ftp-stud.fht-esslingen.de/pub/Mirrors/ftp.proftpd.net/distrib/source/ \
                    ftp://mirror.hostfuss.com/proftpd/distrib/source/ \
                    ftp://ftp.piotrkosoft.net/pub/mirrors/ftp.proftpd.org/distrib/source/ \
                    ftp://proftpd.get7.biz/proftpd/distrib/source/ \
                    ftp://ftp.ibiblio.org/pub/mirrors/proftpd/distrib/source/ \
                    ftp://ftp.solnet.ch/mirror/proftpd.org/distrib/source/ \
                    gentoo

depends_build       port:libtool

depends_lib         port:libidn \
                    port:libsodium \
                    port:ncurses

# https://github.com/proftpd/proftpd/issues/1879
# https://github.com/proftpd/proftpd/issues/1881
# remove the following line when updating to 1.3.10
use_autoconf        yes
configure.args      --sysconfdir=${prefix}/etc/${name} \
                    --localstatedir=${prefix}/var/run/${name} \
                    --mandir=${prefix}/share/man \
                    --enable-ctrls \
                    --enable-dso \
                    --enable-openssl \
                    install_user=`id -u` \
                    install_group=`id -g`

patch.pre_args-replace  -p0 -p1
 patchfiles          patch-lib-pr_fnmatch.diff

# only one --with-modules arg can be used, likewise --with-{includes,libraries}
set modules [list mod_tls mod_sftp mod_sftp_pam mod_ban mod_ctrls_admin \
                  mod_dynmasq mod_exec mod_ifsession mod_load mod_log_forensic \
                  mod_qos mod_quotatab mod_quotatab_file mod_ratio mod_readme \
                  mod_rewrite mod_shaper mod_site_misc mod_unique_id]
set includes {}
set libs {}
pre-configure {
    if {[lsearch -glob ${modules} mod_sql_*] != -1} {
        lappend modules mod_sql mod_sql_passwd
    }
    configure.args-append --with-modules=[join $modules :]
    configure.args-append --with-shared=[join $modules :]
    if {$includes != {}} {
        configure.args-append --with-includes=[join $includes :]
    }
    if {$libs != {}} {
        configure.args-append --with-libraries=[join $libs :]
    }
}

pre-destroot {
    reinplace "s|nogroup|nobody|g" ${worksrcpath}/sample-configurations/basic.conf
    xinstall -m 755 -d ${destroot}${prefix}/var/run/${name}
    touch ${destroot}${prefix}/var/run/${name}/${name}.scoreboard
}

post-destroot {
    move ${destroot}${prefix}/etc/${name}/${name}.conf ${destroot}${prefix}/etc/${name}/${name}.conf.dist
    move ${destroot}${prefix}/var/run/${name}/${name}.scoreboard ${destroot}${prefix}/var/run/${name}/${name}.scoreboard.dist
}

post-activate {
    # move the .conf from an old install
    if {[file exists ${prefix}/etc/${name}.conf]} {
        move ${prefix}/etc/${name}.conf ${prefix}/etc/${name}/${name}.conf
    }
    if {![file exists ${prefix}/etc/${name}/${name}.conf]} {
        copy ${prefix}/etc/${name}/${name}.conf.dist ${prefix}/etc/${name}/${name}.conf
    }
}

set mysql_vers {57 8}
set mysql_names [lmap v ${mysql_vers} {string cat mysql ${v}}]
set mariadb_vers {10.11 11.8 12.3}
set mariadb_names [lmap v ${mariadb_vers} {string cat mariadb [lindex [split ${v} .] 0]}]
set pgsql_vers {14 15 16 17 18}
set pgsql_names [lmap v ${pgsql_vers} {string cat postgresql ${v}}]
set db_vers [list {*}${mysql_names} {*}${mariadb_names} {*}${pgsql_names} "sqlite3"]

foreach v ${mysql_vers} {
    set mysql_name [string cat mysql ${v}]
    variant ${mysql_name} \
            conflicts {*}[ldelete ${db_vers} ${mysql_name}] \
            description "Build with MySQL${v} support" "
        depends_lib-append      port:${mysql_name}
        lappend modules mod_sql_mysql
        lappend includes ${prefix}/include/${mysql_name}/mysql
        lappend libs ${prefix}/lib/${mysql_name}/mysql
    "
}

foreach v ${mariadb_vers} {
    set mariadb_name [string cat mariadb [lindex [split ${v} .] 0]]
    variant ${mariadb_name} \
            conflicts {*}[ldelete ${db_vers} ${mariadb_name}] \
            description "Build with mariadb-${v} support" "
        depends_lib-append      port:mariadb-${v}
        lappend modules mod_sql_mysql
        lappend includes ${prefix}/include/mariadb-${v}/mysql
        lappend libs ${prefix}/lib/mariadb-${v}/mysql
    "
}

foreach v ${pgsql_vers} {
    set pgsql_name [string cat postgresql ${v}]
    variant ${pgsql_name} \
            conflicts {*}[ldelete ${db_vers} ${pgsql_name}] \
            description "Build with ${pgsql_name} support" "
        depends_lib-append      port:${pgsql_name}
        lappend modules mod_sql_postgres
        lappend includes ${prefix}/include/${pgsql_name}
        lappend libs ${prefix}/lib/${pgsql_name}
    "
}

variant sqlite3 \
        conflicts {*}[ldelete ${db_vers} "sqlite3"] \
        description {Build with sqlite3 support} {
    depends_lib-append      port:sqlite3
    lappend modules mod_sql_sqlite
}

variant quotasql description {Build with SQL quota support} {
    lappend modules mod_quotatab_sql
}

set none_selected 1
foreach db_ver ${db_vers} {
    if {[variant_isset ${db_ver}]} {
        set none_selected 0
        break
    }
}

if {${none_selected}} {
    default_variants +[lindex ${mariadb_names} end]
}

notes "
On activation, if no ${prefix}/etc/${name}/${name}.conf file exists,
one will be created

If a ${prefix}/etc/${name}/${name}.cnf file exists, MacPorts does not
touch it, and any changes you make to ${prefix}/etc/${name}/${name}.cnf
will be preserved (e.g., during port upgrades, deactivations or
activations).

If you are upgrading from 1.3.8, the old  ${prefix}/etc/${name}.cnf
will be moved to ${prefix}/etc/${name}/${name}.cnf
"

startupitem.create  yes
startupitem.start   "${prefix}/sbin/${name}"
startupitem.restart "/bin/kill -HUP \$(/bin/cat ${prefix}/var/run/${name}/${name}.pid)"
startupitem.stop    "/bin/kill -15 \$(/bin/cat ${prefix}/var/run/${name}/${name}.pid)"
